% File:       MF Inputs cigma.mf
% Author:     Pierre A. MacKay
% Internet:   mackay@cs.washington.edu
% Date:       Friday, 06 May 1994
% Copyright 1994 by Pierre A. MacKay
% The contents of this file are licensed free for
% use and redistribution under the terms of the  
% GNU General Public License.  For the terms of  
% this license see any publication of the Free   
% Software Foundation or any software packages   
% distributed by the Free Software Foundation.   
% 
def dims=8u#,x_height#,desc_depth# enddef;
def ital = 0 enddef;
def fit_params = 0,0 enddef;

def gen_letter =
  pickup fine.nib;
  pos4(hair,-180); y4=.5h; lft x4r=hround .75u;			%left bulge
  pos6(hair,-90); rt x6l=hround(w-.75u);          		%bottom right
  top y3r=h+oo; x3+.5stem=rt x6l; pos3(stem,90);		%top right
  pos5(stem,-90); bot y5r=-o; x5=.5w;				%low pt
%  bot y6r= top y5l; 
  bot y6 = 0;                     % The rise y5-y6 must be very slight.
                                  % In some hands, it is even a drop.
  filldraw double_circ_stroke					%bowl
    z6e...z5e{left}...z4e{up}...z3e{right};
enddef;

cmchar "Lowercase lunate sigma";
beginchar(lunate_cigma,dims);
this_letter; penlabels(1,2,3,4,5,6,7,8); endchar;

picture savedpicture;