% Copyright 1986 Michael Urban
% Everyone is granted permission to copy, modify and redistribute
% this file, provided that a currently-dated copy of this
% copyright notice is included in the copy.
% License is granted to produce fonts based on the information
% in this file, provided that such fonts are redistributed
% without charge to any third party.

% SCCS ID @(#)punctuation.mf        1.1   10/1/86

beginchar ("(", 3*leadgap#, cap#, 0); "The character (";
	x1 = x3 = w;
	x2 = leadgap;
	y1 = h;
	y2 = .5[y1,y3];
	y3 = 0;
	pickup elvishpen;
	draw z1..z2..z3;
endchar;

beginchar (")", 3*leadgap#, cap#, 0); "The character )";
	x1 = x3 = leadgap;
	x2 = w;
	y1 = h;
	y2 = .5[y1,y3];
	y3 = 0;
	pickup elvishpen;
	draw z1..z2..z3;
endchar;

beginchar (",", 3*leadgap#, xht#, 0); "The punctuation comma (one dot)";
        begingroup;
        save x, y;
        pickup pensquare scaled thick rotated 45;
        z1 = (1/2w, h/2);
        drawdot z1;
        endgroup;
endchar;

beginchar (";", 2*leadgap#, xht#, 0); "The punctuation semicolon (two dots)";
        begingroup;
        save x, y;
        pickup pensquare scaled thick rotated 45;
        z1 = (w/2, h-2thin);
        z2 = (w/2, 2thin);
        drawdot z1;
        drawdot z2;
        endgroup;
endchar;

beginchar (".", 3*leadgap#, xht#, 0); "The punctuation period (four dots)";
        begingroup;
        save x, y;
        pickup pensquare scaled thick rotated 45;
        z1 = (w/3, h-2thin);
        z2 = (w/3, 2thin);
        z3 = (w, h-2thin);
        z4 = (w, 2thin);
        drawdot z1;
        drawdot z2;
        drawdot z3;
        drawdot z4;
        endgroup;
endchar;

beginchar ("!", .7shortwidth, cap#, 0); "The exclamation point";
        begingroup;
        save x, y;
        pickup elvishpen;
        rt x1 = w; top y1=h; bot y4=2thick;
        y2 = y3 = .5[y1,y4];
        z1-z2 = z3-z4 = whatever*(dir 40);
        x4 = leadgap;
        draw z1..controls z2 and z3..z4;
        pickup pensquare scaled thick rotated 45;
        z5 = (leadgap + .5thick, thick);
        drawdot z5;
        endgroup;
endchar;

beginchar ("?", .7shortwidth, cap#, 0); "The question mark";
        begingroup;
        save x, y;
        pickup elvishpen;
        z1 = (leadgap, h);
        top y2 = h; x2 = .6[leadgap, w];
        rt x3 = w; y3 = .7(h - xht) + xht;
        lft x4 = leadgap; bot y4 = xht;
        lft x6 = leadgap; y6 = 2thick;
        draw z1..tension 2.0..z2..z3..z4--z6;
        pickup pensquare scaled thick rotated 45;
        z5 = (leadgap + .5thick, thick);
        drawdot z5;
        endgroup;
endchar;

beginchar ("-", shortwidth, xht#, 0); "The dash (tilde)";
        begingroup;
        save x, y;
        pickup elvishpen;
        x1 = leadgap; 
        x4 = w; 
        y1 = .4h; y4 = .6h;
        z2-z1 = z4-z3 = whatever*(dir tilt);
        y2-y1 = 3 (y4-y1);
        draw z1..controls z2 and z3..z4;
        endgroup;
endchar;

beginchar (oct"173", 1.5*shortwidth, xht#, 0); "en dash";
        begingroup;
        save x, y;
        pickup elvishpen;
        x1 = leadgap; 
        x4 = w; 
        y1 = .4h; y4 = .6h;
        z2-z1 = z4-z3 = whatever*(dir tilt);
        y2-y1 = 3 (y4-y1);
        draw z1..controls z2 and z3..z4;
        endgroup;
endchar;

beginchar (oct"174", 3*shortwidth, xht#, 0); "em dash";
        begingroup;
        save x, y;
        pickup elvishpen;
        x1 = leadgap; 
        x4 = w; 
        y1 = .4h; y4 = .6h;
        z2-z1 = z4-z3 = whatever*(dir tilt);
        y2-y1 = 3 (y4-y1);
        draw z1..controls z2 and z3..z4;
        endgroup;
endchar;

beginchar ("=", shortwidth, xht#, 0); "The equals";
        begingroup;
        save x, y;
        pickup elvishpen;
        x1 = leadgap; 
        x4 = w; 
        y1 = .8h; y4 = 1h;
        z2-z1 = z4-z3 = whatever*(dir tilt);
        y2-y1 = 3 (y4-y1);
        draw z1..controls z2 and z3..z4;
        x5 = x1; x6 = x2; x7 = x3; x8 = x4;
        y5 = y1 - 2thick; y6 = y2 - 2thick; y7 = y3 - 2thick; y8 = y4 - 2thick;
        draw z5..controls z6 and z7..z8;
        endgroup;
endchar;

beginchar ("~", shortwidth, cap#, 0); "The tilde";
        begingroup;
        save x, y;
        pickup elvishpen;
        x1 = leadgap; 
        x4 = w; 
        y1 = .8h; y4 = .7h;
        z2-z1 = z4-z3 = whatever*(dir tilt);
        y2-y1 = 3 (y4-y1);
        draw z1..controls z2 and z3..z4;
        endgroup;
endchar;